;Hatchset.lsp V1.5  Bill DeShawn copyright 2-25-06
;All rights to edit are hereby denied except by permission.
;No responsibility for damage is assumed by author.  Use at your own risk.
(defun c:hatchset (/ ent elist layr colr lt)
   (command "_undo" "_g")
   (setq ent (entsel))
   (setq elist (entget (car ent)))
   (setq layr (cdr (assoc 8 elist)))
   (setq colr (cdr (assoc 62 elist)))
   (setq lt (cdr (assoc 6 elist)))
   (setvar "hpname" (cdr (assoc 2 elist)))
   (if (/= (getvar "hpname") "SOLID")
      (progn
         (setvar "hpang" (cdr (assoc 52 elist)));No need for RTD here.  Don't ask me why.  The value returned is in radians!
         (setvar "hpscale" (cdr (assoc 41 elist)))
      )
   )
   (if (or (= (substr (getvar "hpname")1 2 ) "_U")(= (substr (getvar "hpname")1 1 ) "U"))
      (progn
         (if (= (cdr (assoc 78 elist)) 2) (setvar "hpdouble" 1))
         (if (= (cdr (assoc 78 elist)) 1) (setvar "hpdouble" 0))
         (setvar "hpspace" (cdr (assoc 41 elist)))
      )
   )
   (command "_.-layer" "s" layr "")
   (if (null colr) (setvar "cecolor" "256") (setvar "cecolor" (itoa (cdr (assoc 62 elist)))))
   (if (null lt) (setvar "celtype" "BYLAYER") (setvar "celtype" (cdr (assoc 6 elist))))
   (if colr (alert (strcat "Entity colors are set to " (itoa colr) ".")))
   (if lt (alert (strcat "Entity linetypes are set to " lt ".")))
   (command "_.undo" "_end")
   (if c:r (c:r)(redraw))
   (princ)
)